/*-------------------------------------
  DLoad Test
-------------------------------------*/


#include "StartUp.XA"

	BA($c000)
	ZEROORG($40)
	CHARSET_PET



DLoad_Install	= $8000
LdLoc		= $500
IrqLine1	= $82
IrqLine2	= $92

	sta $d07a		;1Mhz on SCPU
	jsr DLoad_Install
	bcc FastLoadInstallOk
	lda #<Text_FastLoadErr
	ldy #>Text_FastLoadErr
	jmp $ab1e

FastLoadInstallOk:
	sei
	lda #$7f
	sta $dc0d
	lda #$35
	sta 1
	lda #$1b
	sta $d011
	lda #IrqLine1
	sta $d012
	lda #$81
	sta $d01a
	lda $d019
	sta $d019
	lda #<irq0
	sta $fffe
	lda #>irq0
	sta $ffff
	cli

	lda #FileName_len
	ldx #<FileName
	ldy #>FileName
	jsr LdLoc			;Load File
        jsr LdLoc+15                    ;Speeder off
	sei
	lda #$37
	sta 1
	lda #0
	sta $d01a
	lda $d019
	sta $d019
	lda #$81
	sta $dc0d
	lda #$0e
	sta $d020
	lda #$06
	sta $d021
	cli
	lda #0
	sta $800
	jsr $a659
	jmp $a7ae

irq0:
	pha
        lda 1
        pha
        lda #$35
        sta 1
        lda $d019
	sta $d019
	lda #6
	sta $d020
	lda #$0e
	sta $d021
	lda #IrqLine2
	sta $d012
	lda #<irq1
	sta $fffe
	lda #>irq1
	sta $ffff
        pla
        sta 1
        pla
	rti

irq1:
	pha
        lda 1
        pha
        lda #$35
        sta 1
        lda $d019
	sta $d019
	lda #$0e
	sta $d020
	lda #$06
	sta $d021
	lda #IrqLine1
	sta $d012
	lda #<irq0
	sta $fffe
	lda #>irq0
	sta $ffff
        pla
        sta 1
        pla
	rti


Text_FastLoadErr:
        .PSC "error installing fastload!",13,0
FileName:
	.PSC "test"
FileName_len = * - FileName

